Writing multiline file fragments in Puppet mostly resulted in code that was hard to read, mostly due to indentation. With Puppet 4, the heredoc style was added. It is now possible to specify a heredoc tag and marker:

$motd_content = @(EOF)
  This system is managed by Puppet
  local changes will be overwritten by next Puppet run.
EOF

The heredoc tag starts with an @ sign followed by arbitrary string enclosed in parenthesis. The heredoc marker is the string given in the tag.

If variables are required inside the heredoc document, the variable interpolation can be enabled by putting the tag string in double quotes. Variables inside the heredoc are written like Puppet DSL variables: a dollar sign followed by the scope and the variable name:

$motd_content = @("EOF")
  Welcome to ${::fqdn}.
  This system is managed by Puppet version ${::puppetversion}.
  Local changes will be overwritten by the next Puppet run
EOF

Normally, heredoc does not handle escape sequences. Escape sequences need to be enabled explicitly. As of Puppet 4.2, heredoc has the following escape sequences available:

Enabled escape sequences have to be placed behind the string of the heredoc tag:

$modt_content = @("EOF"/tn)
Welcome to ${::fqdn}.
	This system is managed by Puppet version ${::puppetversion}.
	Local changes will be overwritten on next Puppet run.
EOF

In the example, the text always starts in the first column, which makes it hard to read and stands out from the code around it, which will usually be indented by some amount of whitespace.

It is possible to strip indentation by placing whitespaces and a pipe sign in front of the heredoc marker. The pipe sign will indicate the first character of each line:

$motd_content = @("EOF")
    Welcome to ${::fqdn}.
    This system is managed by Puppet version ${::puppetversion}.
    Local changes will be overwritten on next Puppet run.
    | EOF

Now heredoc and inline_epp can be easily combined:

class my_motd (
  Optional[String] $additional_content = undef
){
  $motd_content = @(EOF)
    Welcome to <%= $::fqdn %>.
    This system is managed by Puppet version <%= $::puppetversion %>.
    Local changes will be overwritten on next Puppet run.
    <% if $additional_content != undef { -%>
    <%= $additional_content %>
    <% } -%>
    | EOF
  file { '/etc/motd':
    ensure  => file,
    content => inline_epp($motd_content, { additional_content => $additional_content } ),
  }
}

Declaring this class will give the following result in the motd file:

puppet apply -e 'include my_motd'
Welcome to puppetmaster.example.net.
This system is managed by Puppet version 4.2.1.
Local changes will be overwritten on next Puppet run.