Chapter 15. Creating Formulas for Financial Applications
IN THIS CHAPTER
A brief overview of the Excel functions that deal with the time value of money
Formulas that perform various types of loan calculations
Formulas that perform various types of investment calculations
An overview of Excel depreciation functions
It's a safe bet that the most common use of Excel is to perform calculations involving money. Every day, people make hundreds of thousands of financial decisions based on the numbers that are calculated in a spreadsheet. These decisions range from simple (Can I afford to buy a new car?) to complex (Will purchasing XYZ Corporation result in a positive cash flow in the next 18 months?). This chapter discusses basic financial calculations that you can perform with the assistance of Excel.
15.1. The Time Value of Money
The face value of money may not always be what it seems. A key consideration is the time value of money. This concept involves calculating the value of money in the past, present, or future. It is based on the premise that money increases in value over time because of interest earned by the money. In other words, a dollar invested today will be worth more tomorrow.
For example, imagine that your rich uncle decided to give away some money and asked you to choose one of the following options:
Receive $8,000 today.
Receive $9,500 in one year.
Receive $12,000 in five years.
Receive $150 per month for five years.
If your goal is to maximize the amount received, you need to take into account not only the face value of the money but also the time value of the money when it arrives in your hands.
The time value of money depends on your perspective. In other words, you're either a lender or a borrower. When you take out a loan to purchase an automobile, you're a borrower, and the institution that provides the funds to you is the lender. When you invest money in a bank savings account, you're a lender; you're lending your money to the bank, and the bank is borrowing it from you.
Several concepts contribute to the time value of money:
Present Value (PV): This is the principal amount. If you deposit $5,000 in a bank savings account, this amount represents the principal, or present value, of the money you invested. If you borrow $15,000 to purchase a car, this amount represents the principal or present value of the loan. Present Value may be positive or negative.
Future Value (FV): This is the principal plus interest. If you invest $5,000 for five years and earn 3 percent annual interest, your investment is worth $5,796.37 at the end of the five-year term. This amount is the future value of your $5,000 investment. If you take out a three-year auto loan for $15,000 and make monthly payments based on a 5.25 percent annual interest rate, you pay a total of $16,244.97. This amount represents the principal plus the interest you paid. Future Value may be positive or negative, depending on the perspective (lender or borrower).
Payment (PMT): This is either principal or principal plus interest. If you deposit $100 per month into a savings account, $100 is the payment. If you have a monthly mortgage payment of $1,025, this amount is made up of principal and interest.
Interest Rate: Interest is a percentage of the principal, usually expressed on an annual basis. For example, you may earn 2.5 percent annual interest on a bank CD (certificate of deposit). Or your mortgage loan may have a 6.75 percent interest rate.
Period: This represents the point in time when interest is paid or earned (for example, a bank CD that pays interest quarterly, or an auto loan that requires monthly payments).
Term: This is the amount of time of interest. A 12-month bank CD has a term of one year. A 30-year mortgage loan has a term of 360 months.
15.2. Loan Calculations
This section describes how to calculate various components of a loan. Think of a loan as consisting of the following components:
The loan amount
The interest rate
The number of payment periods
The periodic payment amount
If you know any three of these components, you can create a formula to calculate the unknown component.
15.2.1. Worksheet functions for calculating loan information
This section describes six commonly used financial functions: PMT, PPMT, IPMT, RATE, NPER, and PV. For information about the arguments used in these functions, see Table 15.1.
15.2.1.1. PMT
The PMT function returns the loan payment (principal plus interest) per period, assuming constant payment amounts and a fixed interest rate. The syntax for the PMT function is
PMT(rate,nper,pv,fv,type)
The following formula returns the monthly payment amount for a $5,000 loan with a 6 percent annual percentage rate. The loan has a term of four years (48 months).
=PMT(6%/12,48,−5000)
This formula returns $117.43, the monthly payment for the loan. The first argument, rate, is the annual rate divided by the number of months in a year. Also, notice that the third argument (pv, for present value) is negative and represents money owed.
15.2.1.2. PPMT
The PPMT function returns the principal part of a loan payment for a given period, assuming constant payment amounts and a fixed interest rate. The syntax for the PPMT function is
PPMT(rate,per,nper,pv,fv,type)
The following formula returns the amount paid to principal for the first month of a $5,000 loan with a 6 percent annual percentage rate. The loan has a term of four years (48 months).
=PPMT(6%/12,1,48,−5000)
The formula returns $92.43 for the principal, which is about 78.7 percent of the total loan payment. If I change the second argument to 48 (to calculate the principal amount for the last payment), the formula returns $116.84, or about 99.5 percent of the total loan payment.
NOTE
To calculate the cumulative principal paid between any two payment periods, use the CUMPRINC function. This function uses two additional arguments: start_period and end_period. In Excel versions prior to Excel 2007, CUMPRINC is available only when you install the Analysis ToolPak add-in.
15.2.1.3. IPMT
The IPMT function returns the interest part of a loan payment for a given period, assuming constant payment amounts and a fixed interest rate. The syntax for the IPMT function is
IPMT(rate,per,nper,pv,fv,type)
The following formula returns the amount paid to interest for the first month of a $5,000 loan with a 6 percent annual percentage rate. The loan has a term of four years (48 months).
=IPMT(6%/12,1,48,−5000)
This formula returns an interest amount of $25.00. By the last payment period for the loan, the interest payment is only $0.58.
NOTE
To calculate the cumulative interest paid between any two payment periods, use the CUMIPMT function. This function uses two additional arguments: start_period and end_period. In Excel versions prior to Excel 2007, CUMIPMT is available only when you install the Analysis ToolPak add-in.
15.2.1.4. RATE
The RATE function returns the periodic interest rate of a loan, given the number of payment periods, the periodic payment amount, and the loan amount. The syntax for the RATE function is
RATE(nper,pmt,pv,fv,type,guess)
The following formula calculates the annual interest rate for a 48-month loan for $5,000 that has a monthly payment amount of $117.43.
=RATE(48,117.43,−5000)*12
This formula returns 6.00 percent. Notice that the result of the function is multiplied by 12 to get the annual percentage rate.
15.2.1.5. NPER
The NPER function returns the number of payment periods for a loan, given the loan's amount, interest rate, and periodic payment amount. The syntax for the NPER function is
NPER(rate,pmt,pv,fv,type)
The following formula calculates the number of payment periods for a $5,000 loan that has a monthly payment amount of $117.43. The loan has a 6 percent annual interest rate.
=NPER(6%/12,117.43,−5000)
This formula returns 47.997 (that is, 48 months). The monthly payment was rounded to the nearest penny, causing the minor discrepancy.
15.2.1.6. PV
The PV function returns the present value (that is, the original loan amount) for a loan, given the interest rate, the number of periods, and the periodic payment amount. The syntax for the PV function is
PV(rate,nper,pmt,fv,type)
The following formula calculates the original loan amount for a 48-month loan that has a monthly payment amount of $117.43. The annual interest rate is 6 percent.
=PV(6%/12,48,−117.43)
This formula returns $5,000.21. The monthly payment was rounded to the nearest penny, causing the $0.21 discrepancy.
15.2.2. A loan calculation example
Figure 15.1 shows a worksheet set up to calculate the periodic payment amount for a loan.
NOTE
The workbook described in this section is available on the companion CD-ROM. The file is named loan payment.xlsx.
The loan amount is in cell B1, and the annual interest rate is in cell B2. Cell B3 contains the payment period expressed in months. For example, if cell B3 is 1, the payment is due monthly. If cell B3 is 3, the payment is due every three months, or quarterly. Cell B4 contains the number of periods of the loan. The example shown in this figure calculates the payment for a $25,000 loan at 6.25 percent annual interest with monthly payments for 36 months. The formula in cell B6 is
=PMT(B2*(B3/12),B4,-B1)
Figure 15.1. Using the PMT function to calculate a periodic loan payment amount.
Notice that the first argument is an expression that calculates the periodic interest rate by using the annual interest rate and the payment period. Therefore, if payments are made quarterly on a three-year loan, the payment period is 3, the number of periods is 12, and the periodic interest rate would be calculated as the annual interest rate multiplied by 3/12.
In the worksheet in Figure 15.1, range A9:B11 is set up to calculate the principal and interest amount for a particular payment period. Cell B9 contains the payment period used by the formulas in B10:B11. (The payment period must be less than or equal to the value in cell B4.)
The formula in cell B10, shown here, calculates the amount of the payment that goes toward principal for the payment period in cell B9:
=PPMT(B2*(B3/12),B9,B4,-B1)
The following formula, in cell B11, calculates the amount of the payment that goes toward interest for the payment period in cell B9:
=IPMT(B2*(B3/12),B9,B4,-B1)
You should note that the sum of B10 and B11 is equal to the total loan payment calculated in cell B6. However, the relative proportion of principal and interest amounts varies with the payment period. (An increasingly larger proportion of the payment is applied toward principal as the loan progresses.) Figure 15.2 shows the principal and interest portions graphically.
15.2.3. Credit card payments
Do you ever wonder how long it would take to pay off a credit card balance if you make the minimum payment amount each month? Figure 15.3 shows a worksheet set up to make this type of calculation.
Figure 15.2. This chart shows the relative interest and principal amounts for the payment periods of a loan.
NOTE
The workbook shown in Figure 15.3 is available on the companion CD-ROM. The file is named credit card payments.xlsx.
Range B1:B5 stores input values. In this example, the credit card has a balance of $1,000, and the lender charges 21.25 percent annual percentage rate (APR). The minimum payment is 2.00 percent (typical of many credit card lenders). Therefore, the minimum payment amount for this example is $20. You can enter a different payment amount in cell B5, but it must be large enough to pay off the loan. For example, you may choose to pay $50 per month to pay off the balance more quickly. However, paying $10 per month isn't sufficient, and the formulas return an error.
Range B7:B9 holds formulas that perform various calculations. The formula in cell B7, which follows, calculates the number of months required to pay off the balance:
=NPER(B2/12,B5,-B1,0)
The formula in B8 calculates the total amount you will pay. This formula is
=B7*B5
The formula in cell B9 calculates the total interest paid:
=B8-B1
Figure 15.3. This worksheet calculates the number of payments required to pay off a credit card balance by paying the minimum payment amount each month.
In this example, it would take about 123 months (more than ten years) to pay off the credit card balance if the borrower made only the minimum monthly payment. The total interest paid on the $1,000 loan would be $1,468.42. This calculation assumes, of course, that no additional charges are made on the account. This example may help explain why you receive so many credit card solicitations in the mail.
Figure 15.4 shows some additional calculations for the credit card example. For example, if you want to pay off the credit card in 12 months, you need to make monthly payments of $93.23. (This amount results in total payments of $1,118.81 with total interest of $118.81.) The formula in B13 is
=PMT($B$2/12,A13,-$B$1)
Figure 15.4. Column B shows the payment required to pay off the credit card balance for various payoff periods.
15.2.4. Creating a loan amortization schedule
A loan amortization schedule is a table of values that shows various types of information for each payment period of a loan. Figure 15.5 shows a worksheet that uses formulas to calculate an amortization schedule.
Figure 15.5. A loan amortization schedule.
NOTE
This workbook available on the companion CD-ROM. The file is named loan amortization schedule.xlsx.
The loan parameters are entered into B1:B4, and the formulas beginning in row 9 use these values for the calculations. Table 15.2 shows the formulas in row 9 of the schedule. These formulas were copied down to row 488. Therefore, the worksheet can calculate amortization schedules for a loan with as many as 480 payment periods (40 years of monthly payments).
NOTE
Formulas in the rows that extend beyond the number of payments return an error value. The worksheet uses conditional formatting to hide the data in these rows. See Chapter 20 for more information about conditional formatting.
15.2.5. Summarizing loan options by using a data table
The Excel Data Table feature is probably one of the most underutilized tools in Excel. Keep in mind that a data table is not the same as a table (created with Insert
Tables 
Table). A data table is a handy way to summarize calculations that depend on one or two "changing" cells. In this example, I use a data table to summarize various loan options. This section describes how to create one-way and two-way data tables.
NOTE
A workbook that demonstrates one- and two-way data tables is available on the companion CD-ROM. The file is named loan data tables.xlsx.
15.2.5.1. Creating a one-way data table
A one-way data table shows the results of any number of calculations for different values of a single input cell.
Figure 15.6 shows a one-way data table (in B10:I13) that displays three calculations (payment amount, total payments, and total interest) for a loan, using seven interest rates ranging from 7.00 percent to 8.50 percent. In this example, the input cell is cell B2.
Figure 15.6. Using a one-way data table to display three loan calculations for various interest rates.
To create this one-way data table, follow these steps:
Enter the formulas that return the results for use in the data table. In this example, the formulas are in B6:B8.
Enter various values for a single input cell in successive columns. In this example, the input value is interest rate, and the values for various interest rates appear in C10:I10.
Create a reference to the formula cells in the column to the left of the input values. In this example, the range B11:B13 contains simple formulas that reference other cells. For example, cell B11 contains the following formula:
=B6
Select the rectangular range that contains the entries from the previous steps. In this example, select B10:I13.
Choose Data
Data Tools 
What-If Analysis 
Data Table. Excel displays the Data Table dialog box, shown in Figure 15.7.Figure 15.7. The Data Table dialog box.
For the Row input cell field, specify the cell reference that corresponds to the variable in your Data Table column header row. In this example, the Row input cell is B2.
Leave the Column input cell field empty. The Column input field is used for two-way data tables, described in the next section.
(Optional) Format the data table. For example, you may want to apply shading to the row and column headers.
Note that the array formula is not entered into the entire range that you selected in Step 4. The first column and first row of your selection are not changed.
|
15.2.5.2. Creating a two-way data table
A two-way data table shows the results of a single calculation for different values of two input cells. Figure 15.8 shows a two-way data table (in B10:I16) that displays a calculation (payment amount) for a loan, using seven interest rates and six loan amounts.
To create this two-way data table, follow these steps:
Enter a formula that returns the results that will be used in the data table. In this example, the formula is in cell B6. The formulas in B7:B8 are not used.
Create a reference to the formula that will be calculated in the table. This reference goes in the upper-left corner of the data table range. In this example, cell B10 contains the following formula:
=B6
Select the rectangular range that contains the entries from the previous steps. In this example, select B10:I16.
Choose Data
Data Tools 
What-If Analysis 
Data Table. Excel displays the Data Table dialog box. (Refer to Figure 15.7.)For the Row Input Cell field, specify the cell reference that corresponds to the first input cell. In this example, the Row Input cell is B2.
For the Column Input Cell field, specify the cell reference that corresponds to the second input cell. In this example, the ColumnInput cell is B1.
After you create the two-way data table, you can change the calculated cell by changing the cell reference in the upper-left cell of the data table. In this example, you can change the formula in cell B10 to =B8 so that the data table displays total interest rather than payment amounts.
|
Calculation 
Calculation Options 
Automatic Except For Data Tables.15.2.6. Calculating a loan with irregular payments
So far, the loan calculation examples in this chapter have involved loans with regular periodic payments. In some cases, loan payback is irregular. For example, you may loan some money to a friend without a formal agreement as to how he will pay the money back. You still collect interest on the loan, so you need a way to perform the calculations based on the actual payment dates.
Figure 15.9 shows a worksheet set up to keep track of such a loan. The annual interest rate for the loan is stored in cell B1 (named APR). The original loan amount and loan date are stored in row 5. Formulas, beginning in row 6, track the irregular loan payments and perform calculations.
Figure 15.9. This worksheet tracks loan payments that are made on an irregular basis.
Column B stores the payment amount made on the date in column C. Notice that the payments are not made on a regular basis. Also, notice that in two cases (row 11 and row 24), the payment amount is negative. These entries represent additional borrowed money added to the loan balance. Formulas in columns D and E calculate the amount of the payment credited toward interest and principal. Columns F and G keep a running tally of the cumulative payments and interest amounts. Formulas in column H compute the new loan balance after each payment. Table 15.3 lists and describes the formulas in row 6. Note that each formula uses an IF function to determine whether the payment date in column C is missing. If so, the formula returns an empty string, so no data appears in the cell.
NOTE
This workbook is available on the companion CD-ROM. The file name is irregular payments.xlsx.
15.3. Investment Calculations
Investment calculations involve calculating interest on fixed-rate investments, such as bank savings accounts, CDs, and annuities. You can make these interest calculations for investments that consist of a single deposit or multiple deposits.
NOTE
The companion CD-ROM contains a workbook with all the interest calculation examples in this section. The file is named investment calculations.xlsx.
15.3.1. Future value of a single deposit
Many investments consist of a single deposit that earns interest over the term of the investment. This section describes calculations for simple interest and compound interest.
15.3.1.1. Calculating simple interest
Simple interest refers to the fact that interest payments are not compounded. The basic formula for computing interest is
Interest = Principal * Rate * Term
For example, suppose that you deposit $1,000 into a bank CD that pays a 3 percent simple annual interest rate. After one year, the CD matures, and you withdraw your money. The bank adds $30, and you walk away with $1,030. In this case, the interest earned is calculated by multiplying the principal ($1,000) by the interest rate (.03) by the term (one year).
If the investment term is less than one year, the simple interest rate is adjusted accordingly, based on the term. For example, $1,000 invested in a six-month CD that pays 3 percent simple annual interest earns $15.00 when the CD matures. In this case, the annual interest rate multiplies by 6/12.
Figure 15.10 shows a worksheet set up to make simple interest calculations. The formula in cell B7, shown here, calculates the interest due at the end of the term:
=B3*B4*B5
The formula in B8 simply adds the interest to the original investment amount.
Figure 15.10. This worksheet calculates simple interest payments.
15.3.1.2. Calculating compound interest
Most fixed-term investments pay interest by using some type of compound interest calculation. Compound interest refers to interest credited to the investment balance, and the investment then earns interest on the interest.
For example, suppose that you deposit $1,000 into a bank CD that pays 3 percent annual interest rate, compounded monthly. Each month, the interest is calculated on the balance, and that amount is credited to your account. The next month's interest calculation will be based on a higher amount because it also includes the previous month's interest payment. One way to calculate the final investment amount involves a series of formulas (see Figure 15.11).
Column B contains formulas to calculate the interest for one month. For example, the formula in B10 is
=C9*($B$5*(1/12))
The formulas in column C simply add the monthly interest amount to the balance. For example, the formula in C10 is
=C9+B10
At the end of the 12-month term, the CD balance is $1,030.42. In other words, monthly compounding results in an additional $0.42 (compared with simple interest).
Figure 15.11. Using a series of formulas to calculate compound interest.
You can use the FV (Future Value) function to calculate the final investment amount without using a series of formulas. Figure 15.12 shows a worksheet set up to calculate compound interest. Cell B6 is an input cell that holds the number of compounding periods per year. For monthly compounding, the value in B6 would be 12. For quarterly compounding, the value would be 4. For daily compounding, the value would be 365. Cell B7 holds the term of the investment expressed in years.
Figure 15.12. Using a single formula to calculate compound interest.
Cell B9 contains the following formula that calculates the periodic interest rate. This value is the interest rate used for each compounding period.
=B5*(1/B6)
The formula in cell B10 uses the FV function to calculate the value of the investment at the end of the term. The formula is
=FV(B9,B6*B7,,-B4)
The first argument for the FV function is the periodic interest rate, which is calculated in cell B9. The second argument represents the total number of compounding periods. The third argument (pmt) is omitted, and the fourth argument is the original investment amount (expressed as a negative value).
The total interest is calculated with a simple formula in cell B11:
=B10-B4
Another formula, in cell B13, calculates the annual yield on the investment:
=(B11/B4)/B7
For example, suppose that you deposit $5,000 into a three-year CD with a 4.25 percent annual interest rate compounded quarterly. In this case, the investment has four compounding periods per year, so you enter 4 into cell B6. The term is three years, so you enter 3 into cell B7. The formula in B10 returns $5,676.11.
Perhaps you want to see how this rate stacks up against a competitor's account that offers daily compounding. Figure 15.13 shows a calculation with daily compounding, using a $5,000 investment (compare this with Figure 15.12). As you can see, the difference is very small ($679.88 versus $676.11). Over a period of three years, the account with daily compounding earns a total of $3.77 more interest. In terms of annual yield, quarterly compounding earns 4.51%, and daily compounding earns 4.53%.
15.3.1.3. Calculating interest with continuous compounding
The term continuous compounding refers to interest that is accumulated continuously. In other words, the investment has an infinite number of compounding periods per year. The following formula calculates the future value of a $5,000 investment at 4.25 percent compounded continuously for three years:
=5000*EXP(4.25%*3)
The formula returns $5,679.92, which is an additional $0.04 compared with daily compounding.
Figure 15.13. Calculating interest by using daily compounding.
NOTE
You can calculate compound interest without using the FV function. The general formula to calculate compound interest is
Principal * (1 + periodic rate) ^ number of periods
For example, consider a five-year, $5,000 investment that earns an annual interest rate of 4 percent, compounded monthly. The formula to calculate the future value of this investment is
=5000*(1+4%/12)^(12*5)
15.3.2. Future value of a series of deposits
Now, consider another type of investment, one in which you make a regular series of deposits into an account. This type of investment is known as an annuity.
The worksheet functions discussed in the "Loan Calculations" section earlier in this chapter also apply to annuities, but you need to use the perspective of a lender, not a borrower. A simple example of this type of investment is a holiday club savings program offered by some banking institutions. A fixed amount is deducted from each of your paychecks and deposited into an interest-earning account. At the end of the year, you withdraw the money (with accumulated interest) to use for holiday expenses.
Suppose that you deposit $200 at the beginning of each month (for 12 months) into an account that pays 2.5 percent annual interest compounded monthly. The following formula calculates the future value of your series of deposits:
=FV(2.5%/12,12,−200,,1)
This formula returns $2,432.75, which represents the total of your deposits ($2,400) plus the interest ($32.75). The last argument for the FV function is 1, which means that you make payments at the beginning of the month. Figure 15.14 shows a worksheet set up to calculate annuities. Table 15.4 describes the contents of this sheet.
Figure 15.14. This worksheet contains formulas to calculate annuities.
NOTE
The workbook shown in Figure 15.14 is available on the companion CD-ROM. The file is named annuity calculator.xlsx.
| Cell | Formula | Description |
|---|---|---|
| B4 | None (input cell) | Initial investment (can be 0) |
| B5 | None (input cell) | The amount deposited on a regular basis |
| B6 | None (input cell) | The number of deposits made in 12 months |
| B7 | None (input cell) | TRUE if you make deposits at the beginning of period; FALSE otherwise |
| B10 | None (input cell) | The length of the investment, in years (can be fractional) |
| B13 | None (input cell) | The annual interest rate |
| B16 | =B4 | Displays the initial investment amount |
| B17 | =B5*B6*B10 | Calculates the total of all regular deposits |
| B18 | =B16+B17 | Adds the initial investment to the sum of the deposits |
| B19 | =B13*(1/B6) | Calculates the periodic interest rate |
| B20 | =FV(B19,B6*B10,-B5,-B4,IF(B7,1,0)) | Calculates the future value of the investment |
| B21 | =B20-B18 | Calculates the interest earned from the investment |
15.4. Depreciation Calculations
Excel offers five functions to calculate depreciation of an asset over time. Depreciating an asset places a value on the asset at a point in time, based on the original value and its useful life. The function that you choose depends on the type of depreciation method that you use.
Table 15.5 summarizes the Excel depreciation functions and the arguments used by each. For complete details, consult the Excel online Help system.
| Function | Depreciation Method | Arguments[] |
|---|---|---|
| SLN | Straight-line. The asset depreciates by the same amount each year of its life. | Cost, Salvage, Life |
| DB | Declining balance. Computes depreciation at a fixed rate. | Cost, Salvage, Life, Period, [Month] |
| DDB | Double-declining balance. Computes depreciation at an accelerated rate. Depreciation is highest in the first period and decreases in successive periods. | Cost, Salvage, Life, Period, [Factor |
| SYD | Sum of the year's digits. Allocates a large depreciation in the earlier years of an asset's life. | Cost, Salvage, Life, Period |
| VDB | Variable-declining balance. Computes the depreciation of an asset for any period (including partial periods) using the double-declining balance method or some other method you specify. | Cost, Salvage, Life, Start _Period, End_Period, [Factor], [No Switch] |
| [] | ||
[] Arguments in brackets are optional.
Here are the arguments for the depreciation functions:
Cost: Original cost of the asset.
Salvage: Salvage cost of the asset after it has fully depreciated.
Life: Number of periods over which the asset will depreciate.
Period: Period in the life for which the calculation is being made.
Month: Number of months in the first year; if omitted, Excel uses 12.
Start_Period: Starting period for the depreciation calculation.
End_Period: Ending period for the depreciation calculation.
Factor: Rate at which the balance declines; if omitted, it is assumed to be 2 (that is, double-declining).
No Switch: TRUE or FALSE. Specifies whether to switch to straight-line depreciation when depreciation is greater than the declining balance calculation.
Figure 15.15 shows depreciation calculations using the SLN, DB, DDB, and SYD functions. The asset's original cost, $10,000, is assumed to have a useful life of 10 years, with a salvage value of $1,000. The range labeled Depreciation Amount shows the annual depreciation of the asset. The range labeled Value of Asset shows the asset's depreciated value over its life.
NOTE
This workbook is available on the companion CD-ROM. The file is named depreciation calculations.xlsx.
Figure 15.16 shows a chart that graphs the asset's value. As you can see, the SLN function produces a straight line; the other functions produce a curved line because the depreciation is greater in the earlier years of the asset's life.
Figure 15.15. A comparison of four depreciation functions.
Figure 15.16. This chart shows an asset's value over time, using four depreciation functions.
The VBD function is useful if you need to calculate depreciation for multiple periods (for example, years 2 and 3). Figure 15.17 shows a worksheet set up to calculate depreciation using the VBD function. The formula in cell B11 is
=VDB(B2,B4,B3,B6,B7,B8,B9)
Figure 15.17. Using the VBD function to calculate depreciation for multiple periods.
The formula displays the depreciation for the first three years of an asset (starting period of 0 and ending period of 3).