To list the information in a data set, you can create a report with a PROC PRINT step. Then you can enhance the report with additional statements and options to create reports like those shown below.

In this chapter, you learn to

To remove the Obs column, specify the NOOBS option in the PROC PRINT statement.

proc print data=work.example noobs;
   var age height weight fee;
run;

To replace the Obs column and identify observations based on an employee's ID number and last name, you can submit the following program.

proc print data=sales.reps;
    id idnum lastname;
run;

This is HTML output from the program:

If a variable in the ID statement also appears in the VAR statement, the output contains two columns for that variable. In the example below, the variable IDnum appears twice.

proc print data=sales.reps;
    id idnum lastname;
    var idnum sex jobcode salary;
run;

By default, a PROC PRINT step lists all the observations in a data set. You can control which observations are printed by adding a WHERE statement to your PROC PRINT step. There can only be one WHERE statement in a step.

General form, WHERE statement:

For example, the following WHERE statement selects only observations for which the value of Age is greater than 30:

proc print data=clinic.admit;
   var age height weight fee;
   where age>30;
run;

Here is the procedure output from the PROC PRINT step with the WHERE statement:

In the WHERE statement you can specify any variable in the SAS data set, not just the variables that are specified in the VAR statement. The WHERE statement works for both character and numeric variables. To specify a condition based on the value of a character variable, you must

You use the following comparison operators to express a condition in the WHERE statement:

where name='Jones, C.';

where temp ne 212;

where partno lt "BG05";

where id>='1543';

where pulse le 85;

The CONTAINS operator selects observations that include the specified substring. The mnemonic equivalent for the CONTAINS operator is ?. You can use either the CONTAINS keyword or the mnemonic equivalent in your code, as shown below.

where firstname CONTAINS 'Jon';
where firstname ? 'Jon';

You can also use WHERE statements to select observations that meet multiple conditions. To link a sequence of expressions into compound expressions, you use logical operators, including the following:

In the following program, the PROC SORT step sorts the permanent SAS data set Clinic.Admit by the values of the variable Age within the values of the variable Weight and creates the temporary SAS data set Wgtadmit. Then the PROC PRINT step prints the Wgtadmit data set.

proc sort data=clinic.admit out=work.wgtadmit; 
   by weight age;
run;
proc print data=work.wgtadmit;
   var age height weight fee;
   where age>30;
run;

The report displays observations in ascending order of age within weight.

Adding the DESCENDING option to the BY statement sorts observations in ascending order of age within descending order of weight. Notice that DESCENDING applies only to the variable Weight.

proc sort data=clinic.admit out=work.wgtadmit;
   by descending weight age;
run;
proc print data=work.wgtadmit;
   var age height weight fee;
   where age>30;
run;

You might also want to subtotal numeric variables. To produce subtotals, add both a SUM statement and a BY statement to your PROC PRINT step.

The SUM statement in the following PROC PRINT step requests column totals for the variable Fee, and the BY statement produces a subtotal for each value of ActLevel.

proc sort data=clinic.admit out=work.activity;
   by actlevel;
run;
proc print data=work.activity;
   var age height weight fee;
   where age>30;
   sum fee; 
   by actlevel;
run;

In the output, the BY variable name and value appear before each BY group. The BY variable name and the subtotal appear at the end of each BY group.

In the previous example, you may have noticed the redundant information for the BY variable. For example, in the partial PROC PRINT output below, the BY variable ActLevel is identified both before the BY group and for the subtotal.

To show the BY variable heading only once, you can use an ID statement and a BY statement together with the SUM statement. When an ID statement specifies the same variable as the BY statement,

The ID, BY, and SUM statements work together to produce the output shown below. The ID variable is listed only once for each BY group and once for each sum. The BY lines are suppressed. Instead, the value of the ID variable, ActLevel, identifies each BY group.

proc sort data=clinic.admit out=work.activity;
   by actlevel;
run;
proc print data=work.activity;
   var age height weight fee;
   where age>30;
   sum fee; 
   by actlevel; 
   id actlevel;
run;

As another enhancement to your PROC PRINT report, you can request that each BY group be printed on a separate page by using the PAGEBY statement.

General form, PAGEBY statement:

   PAGEBY BY-variable;

where BY-variable identifies a variable that appears in the BY statement in the PROC PRINT step. PROC PRINT begins printing a new page if the value of any of the variables in the BY statement changes.

The PAGEBY statement in the program below prints BY groups for the variable ActLevel separately. The BY groups appear on separate pages in the output.

proc sort data=clinic.admit out=work.activity;
   by actlevel;
run;
proc print data=work.activity;
   var age height weight fee;

   where age>30;
   sum fee; 
   by actlevel; 
   id actlevel; 
   pageby actlevel;
run;

To make your report more meaningful and self-explanatory, you can associate up to 10 titles with procedure output by using TITLE statements before the PROC step. Likewise, you can specify up to 10 footnotes by using FOOTNOTE statements before the PROC step.

General form, TITLE and FOOTNOTE statements:

   TITLE<n> 'text';

   FOOTNOTE<n> 'text';

where n is a number from 1 to 10 that specifies the title or footnote line, and 'text' is the actual title or footnote to be displayed. The maximum title or footnote length depends on your operating environment and on the value of the LINESIZE= option.

The keyword title is equivalent to title1. Likewise, footnote is equivalent to footnote1. If you don't specify a title, the default title is The SAS System. No footnote is printed unless you specify one.

You can also specify titles in the TITLES window and footnotes in the FOOTNOTES window. Titles and footnotes that you specify in these windows are not stored with your program, and they remain in effect only during your SAS session.

To open the TITLES window, issue the TITLES command. To open the FOOTNOTES window, issue the FOOTNOTES command.

To specify a title or footnote, type in the text you want next to the number of the line where the text should appear. To cancel a title or footnote, erase the existing text. Notice that you do not enclose text in quotation marks in these windows.

The two TITLE statements below, specified for lines 1 and 3, define titles for the PROC PRINT output.

title1 'Heart Rates for Patients with'; 
title3 'Increased Stress Tolerance Levels';
proc print data=clinic.stress;
   var resthr maxhr rechr;
   where tolerance='I';
run;

Title lines for HTML output appear differently depending on the version of SAS that you use. In SAS Version 8, title lines simply appear consecutively, without extra spacing to indicate skipped title numbers. In SAS^®9 HTML output, title line 2 is blank.

In SAS listing output for all versions of SAS, title line 2 is blank, as shown below. Titles are centered by default.

The two FOOTNOTE statements below, specified for lines 1 and 3, define footnotes for the PROC PRINT output.

footnote1 'Data from Treadmill Tests'; 
footnote3 '1st Quarter Admissions';
proc print data=clinic.stress;
   var resthr maxhr rechr;
   where tolerance='I';
run;

Footnotes appear at the bottom of each page of procedure output. Notice that footnote lines are pushed up from the bottom. The FOOTNOTE statement that has the largest number appears on the bottom line.

In HTML output, footnote lines simply appear consecutively, without extra spacing to indicate skipped footnote numbers.

In SAS listing output, footnote line 2 is blank, as shown below. Footnotes are centered by default.

TITLE and FOOTNOTE statements are global statements. That is, after you define a title or footnote, it remains in effect until you modify it, cancel it, or end your SAS session.

For example, the footnotes that are assigned in the PROC PRINT step below also appear in the output from the PROC TABULATE step.

footnote1 'Data from Treadmill Tests'; 
footnote3 '1st Quarter Admissions';
proc print data=clinic.stress;
   var resthr maxhr rechr;
   where tolerance='I';
run;
proc tabulate data=clinic.stress;
   where tolerance='I';
   var resthr maxhr;
   table mean*(resthr maxhr);
run;

Redefining a title or footnote line cancels any higher-numbered title or footnote lines, respectively. In the example below, defining a title for line 2 in the second report automatically cancels title line 3.

title3 'Participation in Exercise Therapy';
proc print data=clinic.therapy;
   var swim walkjogrun aerclass;
run;
title2 'Report for March';
proc print data=clinic.therapy;
run;

To cancel all previous titles or footnotes, specify a null TITLE or FOOTNOTE statement (a TITLE or FOOTNOTE statement with no number or text) or a TITLE1 or FOOTNOTE1 statement with no text. This will also cancel the default title The SAS System.

For example, in the program below, the null TITLE1 statement cancels all titles that are in effect before either PROC step executes. The null FOOTNOTE statement cancels all footnotes that are in effect after the PROC PRINT step executes. The PROC TABULATE output appears without a footnote.

title1; 
footnote1 'Data from Treadmill Tests'; 
footnote3 '1st Quarter Admissions';
proc print data=clinic.stress;
   var resthr maxhr rechr;
   where tolerance='I';
run;
footnote;
proc tabulate data=clinic.stress;
   var timemin timesec;
   table max*(timemin timesec);
run;

You can also enhance your PROC PRINT report by labeling columns with more descriptive text. To label columns, you use

General form, LABEL statement:

   LABEL variable1='label1'

         'variable2='label2'

         … ;

Labels can be up to 256 characters long. Enclose the label in quotation marks.

In the PROC PRINT step below, the variable name WalkJogRun is displayed with the label Walk/Jog/Run. Note the LABEL option in the PROC PRINT statement.

proc print data=clinic.therapy label;
   label walkjogrun='Walk/Jog/Run';
run;

You can assign labels in separate LABEL statements . . .

proc print data=clinic.admit label;
   var age height;
   label age='Age of Patient'; 
   label height='Height in Inches';
run;

…oryoucan assign any number of labels in a single LABEL statement.

proc print data=clinic.admit label;
   var actlevel height weight;

label actlevel='Activity Level'
   height='Height in Inches' 
   weight='Weight in Pounds';
run;

In your SAS reports, formats control how the data values are displayed. To make data values more understandable when they are displayed in your procedure output, you can use the FORMAT statement, which associates formats with variables.

Formats affect only how the data values appear in output, not the actual data values as they are stored in the SAS data set.

General form, FORMAT statement:

   FORMAT variable(s) format-name;

where

• variable(s) is the name of one or more variables whose values are to be written according to a particular pattern

• format-name specifies a SAS format or a user-defined format that is used to write out the values.

You can use a separate FORMAT statement for each variable, or you can format several variables (using either the same format or different formats) in a single FORMAT statement.

format date mmddyy8.;

format net comma5.0
      gross comma8.2;

5,678.90

format net gross dollar9.2;

$5,678.90

For example, the FORMAT statement below writes values of the variable Fee using dollar signs, commas, and no decimal places.

proc print data=clinic.admit;
   var actlevel fee;

   where actlevel='HIGH';
   format fee dollar4.;
run;

The table below describes some SAS formats that are commonly used in reports.

All SAS formats specify the total field width (w) that is used for displaying the values in the output. For example, suppose the longest value for the variable Net is a four-digit number, such as 5400. To specify the COMMA w.d format for Net, you specify a field width of 5 or more. You must count the comma, because it occupies a position in the output.

For numeric variables you can also specify the number of decimal places (d), if any, to be displayed in the output. Numbers are rounded to the specified number of decimal places. In the example above, no decimal places are displayed.

Writing the whole number 2030 as 2,030.00 requires eight print positions, including two decimal places and the decimal point.

Formatting 15374 with a dollar sign, commas, and two decimal places requires ten print positions.

This table shows you how data values are displayed when different format, field width, and decimal place specifications are used.

LIBNAME libref 'SAS-data-library';

OPTIONS options;

PROC SORT DATA=SAS-data-setOUT=SAS-data-set;

      BY variable(s);

RUN;

TITLE<n> 'text';

FOOTNOTE<n>'text';

PROC PRINT DATA=SAS-data-set

      NOOBS LABEL DOUBLE;

      ID variable(s);

      VAR variable(s);

      WHERE where-expression;

      SUM variable(s);

   LABEL variable1='label1' variable2='label2' …;

   FORMAT variable(s) format-name;

RUN;

libname clinic 'c:stresslabdata';
options nodate number pageno=15;
proc sort data=clinic.stress out=work.maxrates;
   by maxhr;
run;
proc print data=work.maxrates label double noobs;
   id name;
   var resthr maxhr rechr date;
   where tolerance='I' and resthr>90;
   sum fee;
   label rechr='Recovery HR';
run;
title 'August Admission Fees';
footnote 'For High Activity Patients';
proc print data=clinic.admit label;
   var actlevel fee;
   where actlevel='HIGH';

   label fee='Admission Fee';
   format fee dollar4.;
run;