If you completed Chapter 4, "Creating List Reports," on page 99, you learned to associate formats with variables either temporarily or permanently.

But sometimes you might want to create custom formats for displaying variable values. For example, you can format a product number so that it is displayed as descriptive text, as shown below.

Using the FORMAT procedure, you can define your own formats for variables. You can store your formats temporarily or permanently, and you can display a list of all your formats and descriptions of their values.

In this chapter, you learn to

To begin a PROC FORMAT step, you use a PROC FORMAT statement.

Any time you use PROC FORMAT to create a format, the format is stored in a format catalog. If the SAS data library does not already contain a format catalog, SAS automatically creates one. If you do not specify the LIBRARY= option, the formats are stored in a default format catalog named Work.Formats.

As the libref Work implies, any format that is stored in Work.Formats is a temporary format that exists only for the current SAS session. At the end of the current session, the catalog is erased.

You can store your formats in a permanent format catalog named Formats when you specify the LIBRARY= option in the PROC FORMAT statement.

PROC FORMAT LIBRARY=libref;

But first, you need a LIBNAME statement that associates the libref with the permanent SAS data library in which the format catalog is to be stored. It is recommended, but not required, that you use the word Library as the libref when creating your own permanent formats.

libname library 'c:sasformatslib';
libname library 'c:datasetuplibrary';
libname library 'c:salesancillarylibset';

When you associate a permanent format with a variable in a subsequent DATA or PROC step, you would then use the Library libref to reference the location of the format catalog.

We'll discuss the use of permanent user-defined formats later, after you learn how to create them.

Now, any format that you create in this PROC FORMAT step is stored in a permanent format catalog called Library.Formats.

libname library 'c:sasformatslib';
proc format library=library;
      … ;
run;

In the program above, the catalog Library.Formats is located in the SAS data library C:SasFormatsLib, which is referenced by the libref Library.

Notice that LIB= is an acceptable abbreviation for the LIBRARY= option.

proc format lib=library;

Also notice that you can specify a catalog name in the LIBRARY= option, and you can store formats in any catalog. The catalog name must conform to SAS naming conventions.

proc format lib=library.catalog;

Now that you know how to store your own formats, let's see how to create them.

You can specify a non-inclusive range of numeric values by using the less than symbol (<) to avoid any overlapping. In this example, the range of values from 0 to less than 13 is labeled as child. The next range begins at 13, so the label teenager would be assigned to the values 13 to 19.

proc format lib=library;
      value agefmt
            0-<13='child'
           13-<20='teenager'
           20-<65='adult'
           65-100='senior citizen';
run;

You can also use the keywords LOW and HIGH to specify the lower and upper limits of a variable's value range. The keyword LOW does not include missing numeric values. The keyword OTHER can be used to label missing values as well as any values that are not specifically addressed in a range.

proc format lib=library;
      value agefmt
            low-<13='child'
            13-<20='teenager'
            20-<65='adult'
            65-high='senior citizen'
            other='unknown';
run;

When specifying a label for displaying each range, remember to

To define several formats, you can use multiple VALUE statements in a single PROC FORMAT step. In this example, each VALUE statement defines a different format.

proc format lib=library;
   value jobfmt
         103='manager'
         105='text processor'
         111='assoc. technical writer'
         112='technical writer'
         113='senior technical writer';
   value $respnse
         'Y'='Yes'
         'N'='No'
         'U'='Undecided'
         'NOP'='No opinion';
run;

The SAS log prints notes informing you that the formats have been created.

Because you have defined the JOBFMT format for displaying the values of JobTitle, the format can be used with PROC PRINT for more legible output.

The next section will show how to apply your formats to variables.

Remember that permanent, user-defined formats are stored in a format catalog. For example, the program below stores the format JOBFMT in a catalog named Library.Formats, which is located in the directory C:SasFormatsLib in the Windows environment.

libname library 'c:sasformatslib';
proc format lib=library;
      value jobfmt
            103='manager'
            105='text processor'
            111='assoc. technical writer'
            112='technical writer'
            113='senior technical writer';
run;

To use the JOBFMT format in a subsequent SAS session, you must assign the libref Library again.

libname library 'c:sasformatslib';
data … ;

SAS searches for the format JOBFMT in two libraries, in this order:

SAS uses the first instance of a specified format that it finds.

Just as with SAS formats, you associate a user-defined format with a variable in a FORMAT statement.

data perm.empinfo;
      infile empdata;
      input @9 FirstName $5. @1 LastName $7. +7 JobTitle 3.
            @19 Salary comma9.;
      format salary comma9.2 jobtitle jobfmt.;
run;

Don't worry about @ pointer controls in programs in this chapter, as in @9 FirstName—they don't affect the behavior of formats. To learn more about using @ pointer controls in SAS programs, see Chapter 17, "Reading Raw Data in Fixed Fields," on page 525.

Remember, you can place the FORMAT statement in either a DATA step or a PROC step. By placing the FORMAT statement in a DATA step, you can permanently associate a format with a variable. Note that you do not have to specify a width value when using a user-defined format.

When you submit the PRINT procedure, the output for Perm.Empinfo now shows commas in the values for Salary, and it shows descriptive labels in place of the values for JobTitle.

proc print data=perm.empinfo;
run;

When associating a format with a variable, remember to

libname library 'c:sasformatslib';
proc format lib=library;
   value jobfmt
         103='manager'
         105='text processor'
         111='assoc. technical writer'
         112='technical writer'
         113='senior technical writer';
run;
libname perm 'c:dataperm';
filename empdata 'c:data	emp
ewhires.txt';
data perm.empinfo;
   infile empdata;
   input @9 FirstName $5. @1 LastName $7. +7 JobTitle 3.
            @19 Salary comma9.;
   format salary comma9.2 jobtitle jobfmt.;
run;

Notice that a period is not required at the end of the SAS format COMMA9.2 in the FORMAT statement. The period in this format occurs between the width specification and the decimal place specification. All formats contain periods, but only user-defined formats invariably require periods at the end of the name.

If you do not format all of a variable's values, then those that are not listed in the VALUE statement are printed as they appear in the SAS data set, as shown in the following example:

proc format lib=library;
   value jobfmt
         103='manager'
         105='text processor';
run;

proc print data=perm.empinfo;
run;

When you build a large catalog of permanent formats, it can be easy to forget the exact spelling of a specific format name or its range of values. Adding the keyword FMTLIB to the PROC FORMAT statement displays a list of all the formats in your catalog, along with descriptions of their values.

libname library 'c:sasformatslib';
proc format library=library fmtlib;
run;

When you submit this PROC step, a description of each format in your permanent catalog is displayed as output.

In addition to the name, range, and label, the format description includes the

LIBNAME libref 'SAS-data-library';

PROC FORMAT LIBRARY=librefFMTLIB;

         VALUE format-name

           range1='label1'

           range2'label2'

           …;

RUN;

DATA SAS-data-set;

      INFILE data-file;

      INPUT pointer variable-name informat.;

      FORMAT variable(s) format-name.;

RUN;

libname library 'c:sasformatslib';
proc format library=library fmtlib;

      value jobfmt
         103='manager'
         105='text processor';
run;


data perm.empinfo;
   infile empdata;
   input @9 FirstName $5. @1 LastName $7.
         +7 JobTitle 3. @19 Salary comma9.;
   format salary comma9.2 jobtitle jobfmt.;
run;