The easiest way to generate a printout using the PrintDocument object is to place the object on a form and give the object a PrintPage event handler to generate the pages. When you're ready to print, simply call the object's Print method to send the printout to the default printer. As it builds the pages, the PrintDocument raises its PrintPage event to find out what to draw.

Once you've done this much, it's practically trivial to add a print preview capability to the program. Add a PrintPreviewDialog object to the form and set its Document property to the PrintDocument object that you already created. To display a print preview, simply call the dialog's ShowDialog method. The dialog uses the associated PrintDocument object to generate the necessary preview and displays the result.

Figure 33-1 shows the PrintShapes example program (available as part of this lesson's code download) displaying a four-page print preview that contains a triangle, rectangle, ellipse, and diamond.

Figure 33.1. FIGURE 33-1

The following code shows the program's PrintPage event handler:

' The number of the next page.
Private NextPageNum As Integer = 0

' Print a page.
Private Sub pdocShapes_PrintPage(ByVal sender As System.Object,
 ByVal e As System.Drawing.Printing.PrintPageEventArgs) _
 Handles pdocShapes.PrintPage
    ' These are used to draw the triangle and diamond.
    Dim xmid As Single =
        CSng((e.MarginBounds.Left + e.MarginBounds.Right) / 2)
    Dim ymid As Single =
        CSng((e.MarginBounds.Top + e.MarginBounds.Bottom) / 2)

    ' See which page this is.
    Select Case NextPageNum
        Case 0 ' Draw a triangle.
            Dim trianglePoints() As PointF =
            {
                New PointF(xmid, e.MarginBounds.Top),
                New PointF(e.MarginBounds.Left, e.MarginBounds.Bottom),
                New PointF(e.MarginBounds.Right, e.MarginBounds.Bottom)
            }
            Using thePen As New Pen(Color.Red, 10)
                e.Graphics.DrawPolygon(thePen, trianglePoints)
            End Using

        Case 1 ' Draw a rectangle.
            Using thePen As New Pen(Color.Blue, 10)
                e.Graphics.DrawRectangle(thePen, e.MarginBounds)
            End Using

        Case 2 ' Draw an ellipse.
            Using thePen As New Pen(Color.Green, 10)
                e.Graphics.DrawEllipse(thePen, e.MarginBounds)
            End Using

        Case 3 ' Draw a diamond.
            Dim diamondPoints() As PointF =
            {
                New PointF(xmid, e.MarginBounds.Top),
                New PointF(e.MarginBounds.Right, ymid),
                New PointF(xmid, e.MarginBounds.Bottom),
                New PointF(e.MarginBounds.Left, ymid)
            }
            Using thePen As New Pen(Color.Black, 10)
                e.Graphics.DrawPolygon(thePen, diamondPoints)
            End Using
    End Select

    NextPageNum += 1
    If (NextPageNum > 3) Then
        ' This is the last page. Start over if we print again.
        e.HasMorePages = False

NextPageNum = 0
    Else
        ' We have more pages.
        e.HasMorePages = True
    End If
End Sub

The NextPageNum variable stores the number of the next page for the program to print.

The event handler uses a Select Case statement to determine which shape it should draw. Depending on the page number, it uses the e.Graphics object's DrawPolygon, DrawRectangle, or DrawEllipse method to draw different shapes.

The code uses different Pen objects to draw the various shapes. For example, it draws the triangle with a 10-pixel-wide red pen. The Using statements automatically dispose of the Pens' resources when the program is done with them.

After it draws the current page's shape, the program increments NextPageNum. If the new page number is greater than 3, the program has finished drawing all of the pages (there are 4 of them, numbered starting with 0), so it sets e.HasMorePages to False. It also resets NextPageNum to 0 so the program starts over the next time you click one of the buttons.

If the next page number is not greater than 3, then the program has more pages to print, so it sets e.HasMorePages to True.

The following code shows how the program displays print previews and generates printouts:

' Display a print preview.
Private Sub btnPreview_Click() Handles btnPreview.Click
    ppdShapes.ShowDialog()
End Sub

' Print to the default printer.
Private Sub btnPrint_Click() Handles btnPrint.Click
    pdocShapes.Print()
End Sub

The PrintShapes program described in the preceding section demonstrates the basic techniques you need to print. It uses a PrintPage event handler to draw different shapes on four pages of a printout.

You can print text in much the same way you print shapes. The only real difference is that to draw text you use the e.Graphics object's DrawString method instead of one of the other Graphics methods such as DrawPolygon or DrawEllipse.

Example program PrintText (available as part of this lesson's code download) uses the following code to print a series of names on a single page:

' Print some text on one page.
Private Sub pdocShapes_PrintPage(ByVal sender As System.Object,
 ByVal e As System.Drawing.Printing.PrintPageEventArgs) _
 Handles pdocText.PrintPage
    ' Make a font to use.
    Using theFont As New Font("Times New Roman", 20)
        ' Get the coordinates for the first line.
        Dim x As Integer = e.MarginBounds.Left
        Dim y As Integer = e.MarginBounds.Top

        ' Print some text.
        Dim names() As String =
        {
            "Arsenal", "Burnley", "Chelsea", "Liverpool",
            "Man City", "Portsmouth", "Tottenham", "Wigan"
        }
        For Each name As String In names
            ' Print the name.
            e.Graphics.DrawString(name, theFont, Brushes.Black, x, y)

            ' Move down for the next line.
            y += 30
        Next name
    End Using

    ' We only have one page.
    e.HasMorePages = False
End Sub

The program first creates a large font to use when drawing text. It uses a Using statement to dispose of the font's resources when the program is done with it.

Next the code sets variables x and y to the coordinates where the first name should appear. In this example, the program displays the first line in the upper-left corner of the page's margin bounds.

The program then loops through an array of names. For each name, the program uses the e.Graphics object's DrawString method to draw the name. It then adds 30 to the variable y so the next name is printed farther down the page.

In this lesson: