There are two participants in a drag and drop operation: a drag source and a drop target.

To handle all of the potential interactions among the drag source, the drop target, and the user, you can use several event handlers. Some of these events occur in the drag source and others occur in the drop target.

Table 35-1 summarizes the key drag source events.

The drop target has more events than the drag source. The drag source merely provides data. The drop target can provide a lot more interaction to tell the user what it can do with the data.

Table 35-2 describes the events received by a drop target when data is dragged over it.

Starting a drag is fairly easy. First create an instance of the DataObject class to indicate the type of data being dragged and to hold the data itself. Then simply call a control's DoDrag method, passing it the DataObject.

The DragSource example program (available in this lesson's code download) uses the following code to start dragging text when you press the right mouse button down over its lblDrag control:

' Start a drag.
Private Sub lblDrag_MouseDown(ByVal sender As System.Object,
 ByVal e As System.Windows.Forms.MouseEventArgs) Handles lblDrag.MouseDown
    ' If it's not the right mouse button, do nothing.
    If e.Button <> MouseButtons.Right Then Return

    ' Make the data object.
    Dim data As New DataObject(DataFormats.Text, lblDrag.Text)

    ' Start the drag allowing only copy.
    lblDrag.DoDragDrop(data, DragDropEffects.Copy)
End Sub

The code first checks whether the right mouse button is pressed, and exits if it is not. It then creates a DataObject. It passes the object's constructor the value DataFormats.Text to indicate that it will hold text data, and the text that the object should hold.

Finally, the code calls the Label control's DoDrag method, passing it the DataObject and the value DragDropEffects.Copy to indicate that the drag allows only the copy operation.

This example doesn't bother with the GiveFeedback and QueryContinueDrag event handlers, so that's the extent of its participation in the drag.

Note that a drag is completely separate from the drop target. If a drop target can accept the data, it is free to do so. That means you don't need to wait until you read about the DropTarget example program described in the next section to test the DragSource program. You can test the program right now by using it to drag text data into Word, WordPad, or any other program that accepts dropped text. (Notepad doesn't know how to accept dropped text.)

Before a control can accept a drop, you must set its AllowDrop property to True. If AllowDrop is False, the control will not allow drops no matter what event handlers you create.

The only other thing a drop target must do is provide DragEnter and DragDrop event handlers.

The DragEnter event handler should examine the data available and set the event handler's e.Effect parameter to indicate whether it wants to allow the drop. The drag and drop system automatically changes the mouse cursor to indicate the kind of drop the target allows.

The DropTarget example program (available in this lesson's code download) uses the following DragEnter event handler:

' A drag entered. See if text is available.
Private Sub lblDrop_DragEnter(ByVal sender As Object,
 ByVal e As System.Windows.Forms.DragEventArgs) Handles lblDrop.DragEnter
    ' Allow text data.
    If e.Data.GetDataPresent(DataFormats.Text) Then
        ' Only allow the Copy operation.
        e.Effect = DragDropEffects.Copy
    End If
End Sub

This code checks whether the drag contains text data and, if it does, sets e.Effect to allow the Copy operation.

The DragDrop event handler should use its e.Data parameter to see what data is available and to get it. It should then set e.Effect to indicate what operation it performed, such as Copy or Move so the drag source knows what happened to the data.

The DropTarget example program uses the following DragDrop event handler:

' Accept dropped data.
Private Sub lblDrop_DragDrop(ByVal sender As Object,
 ByVal e As System.Windows.Forms.DragEventArgs) Handles lblDrop.DragDrop
    ' Get the dropped data.
    If e.Data.GetDataPresent(DataFormats.Text) Then
        lblDrop.Text = e.Data.GetData(DataFormats.Text).ToString()

        ' Indicate that we copied.
        e.Effect = DragDropEffects.Copy
    End If
End Sub

This code checks for text data. If text is available, the code gets it and displays it in a label. It also sets e.Effect = DragDropEffects.Copy to tell the drag source that the target performed a Copy operation.

Note that accepting a drop is completely separate from the drag. If data is available in a format that your program can use, you are free to use it. In this case, that means you don't need to use the DragSource example program described in the previous section to test the DropTarget example program. You can also drag text from Word, WordPad, or any other program that knows how to start dragging text. (Notepad doesn't know how to start a drag.)

In this Try It, you elaborate on the DragSource and DropTarget example programs. You modify DragSource so it allows Copy or Move operations.

You make DropTarget perform Copy or Move operations depending on whether the [Ctrl] key is pressed during the drop. You also provide feedback if the user changes the state of the [Ctrl] key during the drag.