Orthogonal and oblique rotations will produce virtually identical solutions in the case where factors are perfectly uncorrelated. As the correlation between latent variables diverges from r = 0.00, the oblique solution will produce increasingly clearer rotated factor patterns.

Using the following syntax, we can try each type of rotation on the engineering data and output a plot of the rotated factor loadings from the pattern matrix. We use ODS to plot the results, and request the plots of the factor loadings by including the PLOTS = LOADINGS option on the FACTOR statement.

ods graphics on/ width = 4in height = 6in;
proc factor data = engdata  nfactors = 2  method = prinit  priors = SMC 
      rotate = VARIMAX plots = loadings ;
   VAR EngProb: INTERESTeng: ;
run;
proc factor data = engdata  nfactors = 2  method = prinit  priors = SMC 
      rotate = QUARTIMAX plots = loadings ;
   VAR EngProb: INTERESTeng: ;
run;
proc factor data = engdata  nfactors = 2  method = prinit  priors = SMC  
      rotate = EQUAMAX plots = loadings ;
   VAR EngProb: INTERESTeng: ;
run;
proc factor data = engdata  nfactors = 2  method = prinit  priors = SMC  
      rotate = PROMAX plots = loadings ;
   VAR EngProb: INTERESTeng: ;
run;
proc factor data = engdata  nfactors = 2  method = prinit  priors = SMC  
      rotate = OBLIMIN plots = loadings ;
   VAR EngProb: INTERESTeng: ;
run;
ods graphics off;

Figure 4.3 Engineering data using different rotation methods presents the rotated factor loading plots for the engineering data using each of the methods summarized earlier in the chapter. The two uppermost plots represent the oblique methods, but the remaining represent the orthogonal methods. Notice that the factor loadings in the oblique plots cluster around the axes. In contrast, the factor loadings in the orthogonal plots tend to cluster around a point slightly away from the axes. This is because these factors are modestly correlated, but the orthogonal mandate to maintain a 90° angle between axes means that the centroids of the clusters cannot move closer to the axis lines.

In this case, the difference between the oblique and orthogonal methods is not great, but it is noticeable. This is a small but clear example of the higher efficacy of oblique rotations to create clear patterns of results in EFA where the factors are indeed correlated. As far as we are aware, there is no rationale for using orthogonal rotation instead of oblique rotation (except tradition). Furthermore, if factors are uncorrelated, orthogonal and oblique solutions will yield very similar results. Thus, if there is uncertainty about the relationship between the factors, we would recommend using an oblique rotation.

We know that choosing between the orthogonal and oblique rotation camps can make a difference in the final results; but how important is the decision about the specific method after you have chosen your camp? Out of the orthogonal methods, varimax rotation is the most commonly used, and it is the default in many programs. One might conclude it is the orthogonal method of choice. Out of the oblique methods, promax rotation is recommended as the most desirable rotation method (Thompson, 2004). Let’s test whether the recommended methods produce different results than their alternatives.

The SDQ contains three scales (parent relations, mathematics, and English) that are minimally correlated (r = 0.15, 0.22, 0.26). Since the theoretical factors are correlated, we should use an oblique rotation method. The two common oblique methods reviewed in this chapter are promax rotation and direct oblimin rotation. The syntax to run these two analyses is presented below. We use maximum likelihood extraction since the method seemed appropriate for this data. (See Chapter 2.)

proc factor data = sdqdata  nfactors = 3  method = ml  rotate = PROMAX;
   VAR Math: Par: Eng:;
run;
proc factor data = sdqdata  nfactors = 3  method = ml  rotate = OBLIMIN;
   VAR Math: Par: Eng:;
run;

Unrotated and rotated factor loadings for SDQ data using direct oblimin rotation and Unrotated and rotated factor loadings for SDQ data using promax rotation display the factor loadings for each of these rotation methods and Factor correlations displays the inter-factor correlations. Both oblique rotation methods yield similar results. As expected, the initial unrotated factor loadings for each method are identical. These should be identical because they represent the distribution of the unique variance of the factor loadings before the factors are rotated. These initial factor loadings would be very difficult to interpret as the loadings for a variable tend to be of moderate size across all of the factors. The rotated factor loadings, in both the pattern matrix and structure matrix, are nearly identical. These solutions are what we would expect given the theoretical model that the scale was developed with. The final rotated solutions give us a clear, theoretically consistent factor structure with subscale items aligning as expected.

In this example, the type of oblique rotation used did not make a difference. They resulted in the same clear factor structures and only minor differences in loadings. Many others (for example, Gorsuch, 1983; Kim & Mueller, 1978) have drawn similar conclusions. The methods within the orthogonal and oblique camps tend to produce similar results.