proc factor data = engdata  nfactors = 2  method = prinit  priors = SMC 
      rotate = oblimin out=factor_scores1 outstat=results score;
   var EngProb: INTERESTeng: ;
run;

*Grab and restructure pattern loadings;
data coeff_oneline (keep=F1_: F2_: merge);
   set results end=last;
   *Array of new variables to contain all loadings in one line;
   array newVar(2,14) F1_EngProbSolv1-F1_EngProbSolv8 F1_INTERESTeng1-
      F1_INTERESTeng6 F2_EngProbSolv1-F2_EngProbSolv8 F2_INTERESTeng1-
      F2_INTERESTeng6;
   *Array of variables containing pattern loadings in input data set;
   array oldVar(*) EngProbSolv1-EngProbSolv8 INTERESTeng1-INTERESTeng6;
   *Retain statement to tell SAS to keep values assigned into these 
      variables across records so that the last record will contain all 
      values assigned;
   retain F1_EngProbSolv1-F1_EngProbSolv8 F1_INTERESTeng1-F1_INTERESTeng6 
      F2_EngProbSolv1-F2_EngProbSolv8 F2_INTERESTeng1-F2_INTERESTeng6;
   *Identify pattern matrix loadings and assign them to the new 
      variables;
   if _TYPE_='PATTERN' and _NAME_='Factor1' then do i=1 to 14;
      newVar(1,i)=oldVar(i);
   end;
   if _TYPE_='PATTERN' and _NAME_='Factor2' then do i=1 to 14;
      newVar(2,i)=oldVar(i);
   end;
   merge=1; *add merge variable so we can merge the resulting one line 
      with all records in student data set;
   *Output the last record in the data set that will contain all the new 
   variables;
   if last then output;
run;
*Assign merge variable to data set containing student records and pre-
   defined SAS factor scores so we can merge the above pattern loadings 
   with each record and compute factor scores based on pattern loadings;
data factor_scores1;
   set factor_scores1;
   merge=1; *add merge variable;
run;
*Compute factor scores based on pattern loadings;
data pattern_score_factorScores (drop=merge F1_: F2_: wt: i f);
   merge factor_scores1 coeff_oneline;
   by merge;
   *Array of variables containing pattern loadings;
   array fact(2,14) F1_EngProbSolv1-F1_EngProbSolv8 F1_INTERESTeng1-
      F1_INTERESTeng6 F2_EngProbSolv1-F2_EngProbSolv8 F2_INTERESTeng1-
      F2_INTERESTeng6;
*Array of responses to items;
   array itms(*) EngProbSolv1-EngProbSolv8 INTERESTeng1-INTERESTeng6;
   *Array that will contain weighted item scores (pattern loading x response);
   array wtItm(*) wt1-wt14;
   *Array that will contain final factor scores based on pattern loadings;
   array fs(*) patternF1 patternF2;
   *Loop from 1 to 2 – representing the factors;
   do f=1 to 2;
      *Loop through each of the 14 items to compute weighted item scores;
      do i=1 to dim(itms);
         wtItm(i)=fact(f,i)*itms(i);
      end;
      *Compute mean of the weighted item scores as the factor score;
      fs(f)=mean(of wt:); *compute mean of weighted estimates as the 
         factor score;
   end;
run;